{*
 * @(#) s_triang.pas - Program for the Square calculation
 * of the specified curve triangle (problem 1).
 * (c) 1995 Ivan Maidanski <ivmai@chat.ru> http://ivmai.chat.ru
 * Freeware program source. All rights reserved.
 **
 * Language: Turbo Pascal
 * Tested with: Turbo Pascal v6.0
 * Last modified: 1995-02-28 16:00:00 GMT+03:00
 *}

program S_of_Triangle;

{ y1(x)=exp(-x)+3; y2(x)=2*x-2; y3(x)=1/x }
{ result_eps=1e-3; method: 3.2.1 }

const Eps= 1e-4;
type TReal= Real;
type TFunc= function (X: TReal): TReal;
function Root(F: TFunc; L,H: TReal): TReal;
 var B: Boolean;
 var X,FL,FH,FX: TReal;
 begin
   FL:=F(L);
   FH:=F(H);
   repeat
     X:=(L*FH-H*FL)/(FH-FL);
     FX:=F(X);
     B:=Abs(FX)<Eps;
     if FX*FL>0
       then begin
              if B
                then B:=Abs(X-L)<Eps;
              L:=X;
              FL:=FX
            end
       else begin
              if B
                then B:=Abs(H-X)<Eps;
              H:=X;
              FH:=FX
            end
   until B;
   Root:=X
 end;
function Integral(F: TFunc; L,H: TReal): TReal;
 var N: Integer;
 var S,LS: TReal;
 procedure Integ;
  var I: Integer;
  var P,X: TReal;
  begin
    P:=(H-L)/N;
    X:=L+P/2;
    S:=0;
    for I:=1 to N
      do begin
           S:=S+F(X);
           X:=X+P
         end;
    S:=S*P
  end;
 begin
   N:=2;
   Integ;
   repeat
     LS:=S;
     N:=2*N;
     Integ
   until Abs(S-LS)<Eps;
   Integral:=S
 end;
function F1(X: TReal): TReal; far;
 begin
   F1:=Exp(-X)-1/X+3
 end;
function F2(X: TReal): TReal; far;
 begin
   F2:=Exp(-X)-2*X+5
 end;
function F3(X: TReal): TReal; far;
 begin
   F3:=2*X-1/X-2
 end;
var X1,X2,X3: TReal;
begin
  X1:=Root(F1,0.1,1);
  X2:=Root(F2,2,3);
  X3:=Root(F3,1,2);
  WriteLn('X1= ',X1:0:4);
  WriteLn('X2= ',X2:0:4);
  WriteLn('X3= ',X3:0:4);
  WriteLn(' S= ',Integral(F1,X1,X3)+Integral(F2,X3,X2):0:4);
  WriteLn
end.